;*********************************
;* C64s v2.52 Reg'd GEMUS Script *
;*       by James Burrows        *
;*         25 July 2001          *
;*********************************
;
; Emulator File:	C64S.EXE
; Associated File (1):	CONFIG.INI
; Use Short Filenames:	YES
; File Types         :  D64;T64
;
; THIS SCRIPT WORKS WITH THE
; REGISTERED 2.52 VERSION ONLY


If GameType CONTAINS(d64||t64)

	;set game control options
	If Control = Keyboard
		Set_INI_Value(1||Config||Joy1||No)
		Set_INI_Value(1||Config||Joy2||No)
	ElseIf Control = JoyPort1
		If NumPlayers > 1
			Set_INI_Value(1||Config||Joy1||Analogue)
			Set_INI_Value(1||Config||Joy2||Keyboard)
		Else
			Set_INI_Value(1||Config||Joy1||Analogue)
			Set_INI_Value(1||Config||Joy2||No)
		End If
	Else
		If NumPlayers > 1
			Set_INI_Value(1||Config||Joy1||Keyboard)
			Set_INI_Value(1||Config||Joy2||Analogue)
		Else
			Set_INI_Value(1||Config||Joy1||No)
			Set_INI_Value(1||Config||Joy2||Keyboard)
		End If
	End If

	;autostart the selected image
	If GameType CONTAINS(d64)
		Add_CLP(-diskdir %gamepath% -disk %gamefile%)
		If ImageName CONTAINS(*)
			Add_CLP( -autotype "LOAD$20$22%imagename%$22,8,1$0DRUN$0D")
		Else
			Add_CLP( -autotype "LOAD$0DRUN$0D")
		End If
	Else
		Add_CLP(-tapedir %gamepath% -tape %gamefile%)
		If ImageName CONTAINS(*)
			Add_CLP( -autotype "LOAD$20$22%imagename%$22$0DRUN$0D")
		Else
			Add_CLP( -autotype "LOAD$0DRUN$0D")
		End If
	End If

	;run the emulator
	Run_Emulator(DOSCLOSE)
Else
	;invalid game file type
	Show_Message(GAME_NOT_SUPPORTED%crlfx2%Supported types: D64, T64)
End If
